let r = 0;
	
	let px = GetPlayerX();
	
	//↑のようにステートメントの最後には
	//「;」が必須です。
 

	//配列の宣言
	let a = [2, 3, 5];//配列aを[2,3,5]で初期化
	
	
	//配列へのアクセス
	//[x]で配列のx番目の値にアクセスします
	//添え字は0からです。
	let b = a[0];//bは2になります
	a[0] = 9;//配列aは[9, 3, 5]になります。
	let str = "あいうえお"[2];//strは'う'になります。
	
	
	//配列の結合
	//「~」演算子で配列の結合を行えます
	let c = [32, 64, 96];
	a = a ~ c;//aは[9, 3, 5, 32, 64, 96]になります。 
	
	
	//配列のテーブルをループで作成する場合
	//配列を結合しながらテーブルを作成できます
	let d = [];//dは配列
	ascent(i in 0..100)
	{//配列dを[0　1　2　…　98　99]で初期化
		d = d ~ [i];//配列の結合
		i++;
	}
	
	
	//配列のスライシング
	//配列に対して[x..y]のようにかくと、
	//要素のx番目からy番目を切り出します
	//ただしy番目の要素は含みません
	let e = [0, 1, 2, 3, 4];
	let f = e[2..4];//fは[2,3]になります
	
	
	//配列を三項演算子の代わりに使う
	let g = [7, -5][b == 10];//bが10ならgは-5になります

	//配列のサイズを取得する	
	let h = [1, 2, 3, 4, 5];
	let i = length(h);//iは5になります		

	//配列要素の削除
	let j = [10, 20, 30, 40];
	j = erase(j, 0);//最初の要素を削除します
	                 //j = [20, 30, 40]になります
 

	//ここで宣言した変数は全域で有効
	let a;//変数aは全ての「@〜」内で有効」
	@Initialize
	{
		a = 2;//変数aにはアクセスできる
		let x = 1;//ここで宣言すると@Initializeの最後まで有効
		local
		{
			//ここで宣言したxはlocal文最後の「}」まで有効
			let x = 3;
			//ここではxは3
			a = x;//aには3が入る
		}
		//ここではxは1
		let c = x;//cには1が入る
	}
		
	@MainLoop
	{
		a = 5;//変数aにはアクセスできる
		//ここでは変数xにアクセスできない
	}
		
	@Finalize
	{
		//while、loop、ifの「{...}」も同様にローカルスコープが導入される
		let d = 10;
		loop(5)
		{
			let e = d;//dにはアクセス可能 
		}
		//ここではeにアクセスできない
	}
	

	let a;
	let b;
	
	a = 32 + 2;	//「+」で和を表します。aは34になります。
	b = a - 30;	//「-」で差を表します。bは4になります。
	a = 2 * 3; 	//「*」で積を表します。aは6になります。
	b = 72 / a;	//「/」で商を表します。bは12になります。
	
	a = 32 % 3;	//「%」は商の余りです。aに32を3で割った余りを代入という意味になります。aは2になります。
	b = a ^ 4;	//「^」は累乗です。bにaの4乗を代入という意味になります。bは16になります。
	b = 3 ^ 3 ^ 3;	//「^」だけ、右結合の演算子です。3^3^3は3^(3^3)と解釈され729ではなく19683になります
	/*
	演算子の優先順位は、
	  「( ... )」 > 「^」「[]」>「!」「+」「-」 (単項)  >「*」「/」「%」 > 「~」「+」 「-」 (二項) 
	です。
	*/
	let c = ((b * 3 - 2)%(a + 2 ^ 2)) / 2;//cは2になります。
	
	//以下のような書き方もできます
	a++;//a = a + 1と同じ
	a+=5;//a = a + 5と同じ

	/*
	基本的な条件式の記述
	「a == b」	：aがbと等しい
	「a > b」	：aがbより大きい
	「a >= b」	：aがb以上
	「a < b」	：aがbより小さい
	「a <= b」	：aがb以下
	*/
	
	//ifの使い方
	if(a == 2 + b * 5)
	{
	//aが「2 + b * 5」であれば実行される部分
	}
	
	//「&&」は論理積を表します。
	if(a > 50 && b < 30)
	{
	//aが50より大きく、bが30より小さいときに実行される
	}
	
	//「||」は論理和を表します。
	if(c >= 2 || b <= 30)
	{
	//cが2以上またはbが30以下のときに実行される
	}
	
	//else は「でなければ」といったような意味です
	if(c == 4)
	{
	//cが4であれば実行される
	}
	else if(d == 6)
	{
	//cが4ではなく、dが6の時実行される
	}
	
	
	//alternativeの使い方
	//C言語のswitchに似た分岐構文です
	alternative(a)
	case(0)
	{
		//aが0の時に実行される
	}
	case(3, 5)
	{
		//aが3もしくは5の時に実行される
	}
	others
	{
		//それ以外の時実行される
	}
		
	//C言語と違いステートメントが1つでも「{」「}」の省略はできません。
	//必ず「{」「}」で囲む必要があります。

	//loopは、()の中に繰り返したい回数を記述します。
	loop(10)
	{
	//10回繰り返します。
	} 

	//回数を省略すると無限ループします。
	//必ずbreak、returnで抜けてください。
	let a = 5;
	loop
	{
		if(a == 5)
		{
			   break;
		}
		a++;
	}

	//timesも()の中に繰り返したい回数を記述します。
	times(5)
	{
	//5回繰り返します。
	} 
	
	//whileは与えられた条件が真の間、範囲を繰り返し実行します。
	let a = 0;
	while(a < 360)
	{//aが360より小さい間繰り返す。
		a++;
	};
	
	//while中が無限ループになると
	//アプリケーションが動かなくなるので注意してください。
	while(true)
	{
	//常に条件が真になり、無限ループになるので危険
	}
	
	//インデックス付きのループもつくれます
	//ascent(let i in x..y) loop{}
	//descent(let i in x..y) loop{}
	//i が x から y まで変化します。ただし y は含みません。
	//ascentは値が増加、descentは減少します。
	ascent( let a in 0..10) loop 
	{
		//array[a] = xxx;配列にアクセスしたりするとき便利です
	}
	
	//ascent、descentともにlet とloopは省略可能です。
	descent(a in 0..10)
	{
		
	}

	let a = 0;
	while(true)
	{//aが5になったらループを抜ける
		if(a==5){break;};
		a++;
	}

	//サブルーチンのかき方例
	sub Shot5Way
	{//5WAYサブルーチン
		let ex = ObjMove_GetX(objEnemy);
		let ey = ObjMove_GetY(objEnemy);
		let angle=-30;
		while(angle<=30)
		{//(angle=-30, -15, 0, 15, 30)
			CreateShotA1(ex, ey, 3, angle, DS_RICE_S_BLUE, 30);
			angle+=15;
		}
	}
	
	
	//サブルーチン呼び出し例
	@MainLoop()
	{
		if(timer == 0)
		{
			Shot5Way;//5WAYサブルーチン呼び出し
		}
	}

	//関数のかき方例
	function nWayToPlayer(let nWayNum,let nWayInterval,let nWaySpeed,let nWayGraphic)
	{//自機方向へのnWay関数
		//nWayNum：nWay
		//nWayInterval：弾の間隔
		//nWaySpeed：弾の速度
		//nWayGraphic：弾の画像

		let ex = ObjMove_GetX(objEnemy);
		let ey = ObjMove_GetY(objEnemy);
		let sAngle =- nWayInterval*int(nWayNum/2);
		let eAngle = nWayInterval*int(nWayNum/2);
		while(sAngle <= eAngle)
		{
			CreateShotA1(ex, ey, nWaySpeed, sAngle, nWayGraphic, 30);
			sAngle+=nWayInterval;
		}
	}
	
	//関数の呼び出し例
	@MainLoop()
	{
		if(timer == 0)
		{//関数呼び出し
			//5Way、弾間隔10°、弾速5、画像BLUE11
			nWayToPlayer(5, 10, 5, DS_RICE_S_RED);
		}
	}

	//返り値の例
	function Double(let x)
	{
		return x * 2;
	}
	
	//〜〜〜
	
	a = Double(10); //a = 20

	@Initialize
	{
		TWork();
	}

	@MainLoop
	{
		//毎ループタスクを実行
		yield;
	}

	//----------------------------------------------------
	//敵動作
	//----------------------------------------------------
	task TWork
	{
		let frame = 0;
		while(!Obj_IsDeleted(objEnemy))
		{
			//敵が削除されるまで8フレーム毎に弾をだす。
			let ex = ObjMove_GetX(objEnemy);
			let ey = ObjMove_GetY(objEnemy);
			if(frame % 8 == 0)
			{
				let i=0;
				while(i<360)
				{
					CreateShotA2(ex, ey, 7, i+frame,-0.4,4,DS_RICE_S_BLUE, 0);//弾を発射
					i+=30;
				}
			}

			frame++;

			//他のタスクに制御を渡す。
			yield;
		}
	}

	//←行末までコメントアウト
	
	
	/*
	この部分は実行されない
	*/

	//----TestA.txt----------------------------
	let valueA = 0;
	function FuncA()
	{
		//〜〜〜
	}


	//----TestB.txt----------------------------
	//TestA.txtを取り込みます。
	//「./」ではじめたパスはこのスクリプトからの相対パスになります。
	//「./」がない場合は、実行ファイルディレクトリからの相対パスになります。
	#include"./TestA.txt"

	function FuncB()
	{
		//#includeでTestA.txtを取り込んでいるため
		//valueAにアクセスできる。
		let valueB = valueA;

		//TestA.txtを取り込んでいるため
		//FuncAを呼び出せる。
		FuncA();
	}